use strict;
use warnings;
use Test::Differences;
use Test::More;
use Test::MockObject;
use Test::Exception;

use Log::Any::Adapter ('Stderr', log_level => "trace");

use App::ImapNotify;
use App::ImapNotify::ImapClient;

=head1 DESCRIPTION

Simulate a connection loss during early stages of the connection.

=cut

my @input_lines = (
	"* OK [CAPABILITY IMAP4rev1 SASL-IR LOGIN-REFERRALS ID ENABLE IDLE LITERAL+ AUTH=PLAIN AUTH=LOGIN] Fake server ready.\r\n",
	"CMD-0 OK [CAPABILITY IMAP4rev1 SASL-IR LOGIN-REFERRALS ID ENABLE IDLE SORT SORT=DISPLAY THREAD=REFERENCES THREAD=REFS THREAD=ORDEREDSUBJECT MULTIAPPEND URL-PARTIAL CATENATE UNSELECT CHILDREN NAMESPACE UIDPLUS LIST-EXTENDED I18NLEVEL=1 CONDSTORE QRESYNC ESEARCH ESORT SEARCHRES WITHIN CONTEXT=SEARCH LIST-STATUS BINARY MOVE SNIPPET=FUZZY LITERAL+ NOTIFY SPECIAL-USE COMPRESS=DEFLATE] Logged in\r\n",
	"CMD-1 OK [READ-WRITE] Select completed (0.001 + 0.000 secs).\r\n",
	"CMD-2 OK NOTIFY completed (0.001 + 0.000 secs).\r\n",
);

my $socket = Test::MockObject->new();
$socket->set_true(qw(writeline reconnect));

my $config = {
	log_id => 'test-id1',
	host => 'localhost.localdomain',
	port => 993,
	username => 'tester1',
	password => 'secretPW42',
	mailboxes => [qw(INBOX INBOX.test)],
	keepalive_timeout => 300,
};

my $imap_client = App::ImapNotify::ImapClient->new_no_defaults($config, {sock => $socket});

my $app = App::ImapNotify->new_no_defaults($config, {imap_client => $imap_client});

$socket->set_series('readline',	undef);
throws_ok {$app->loop();} qr/^Lost connection while waiting for server greeting/, "Expect connection loss";
eq_or_diff([grep { $_->[0] eq "writeline" } $socket->_calls()->@*], [
	], "Connection loss before receiving greeting");
$socket->clear();

$socket->set_series('readline',	@input_lines[0..0], undef);
throws_ok {$app->loop();} qr/^Lost connection while waiting for reply to command 'login tester1 secretPW42'/, "Expect connection loss";
eq_or_diff([grep { $_->[0] eq "writeline" } $socket->_calls()->@*], [
		['writeline', [$socket, "CMD-0 login tester1 secretPW42\r\n"]],
	], "Connection loss after sending login");
$socket->clear();

$socket->set_series('readline',	@input_lines[0..1], undef);
throws_ok {$app->loop();} qr/^Lost connection while waiting for reply to command 'select INBOX'/, "Expect connection loss";
eq_or_diff([grep { $_->[0] eq "writeline" } $socket->_calls()->@*], [
		['writeline', [$socket, "CMD-0 login tester1 secretPW42\r\n"]],
		['writeline', [$socket, "CMD-1 select INBOX\r\n"]],
	], "Connection loss after sending select");
$socket->clear();

$socket->set_series('readline',	@input_lines[0..2], undef);
throws_ok {$app->loop();} qr/^Lost connection while waiting for reply to command 'notify set \(.*\)'/, "Expect connection loss";
eq_or_diff([grep { $_->[0] eq "writeline" } $socket->_calls()->@*], [
		['writeline', [$socket, "CMD-0 login tester1 secretPW42\r\n"]],
		['writeline', [$socket, "CMD-1 select INBOX\r\n"]],
		['writeline', [$socket, "CMD-2 notify set (selected (MessageExpunge MessageNew (uid body.peek[header.fields (from to subject)]))) (mailboxes (INBOX INBOX.test) (MessageNew MessageExpunge MailboxName))\r\n"]],
	], "Connection loss after sending notify");
$socket->clear();

done_testing;