1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
use strict;
use warnings;
use Test::Differences;
use Test::More;
use Test::MockObject;
use Log::Any::Adapter ('Stderr', log_level => "warn");
use App::ImapNotify;
use App::ImapNotify::ImapClient;
=head1 DESCRIPTION
This test simulates a server that doesn't send any notifications. The client
then runs into the keepalive timeout at which point the server just happens to
receive a new message which it returns before the NOOP (keepalive) response.
=cut
my $notifier = Test::MockObject->new();
$notifier->set_true("notify");
my @input_lines = (
"* OK [CAPABILITY IMAP4rev1 SASL-IR LOGIN-REFERRALS ID ENABLE IDLE LITERAL+ AUTH=PLAIN AUTH=LOGIN] Fake server ready.\r\n",
"CMD-0 OK [CAPABILITY IMAP4rev1 SASL-IR LOGIN-REFERRALS ID ENABLE IDLE SORT SORT=DISPLAY THREAD=REFERENCES THREAD=REFS THREAD=ORDEREDSUBJECT MULTIAPPEND URL-PARTIAL CATENATE UNSELECT CHILDREN NAMESPACE UIDPLUS LIST-EXTENDED I18NLEVEL=1 CONDSTORE QRESYNC ESEARCH ESORT SEARCHRES WITHIN CONTEXT=SEARCH LIST-STATUS BINARY MOVE SNIPPET=FUZZY LITERAL+ NOTIFY SPECIAL-USE COMPRESS=DEFLATE] Logged in\r\n",
"CMD-1 OK [READ-WRITE] Select completed (0.001 + 0.000 secs).\r\n",
"CMD-2 OK NOTIFY completed (0.001 + 0.000 secs).\r\n",
# this sub is aborted by the timeout
sub {sleep 10; fail("Keepalive failed to kill readline() operation");},
# notification that got in before the NOOP response
"* 51 FETCH (UID 41023 BODY[HEADER.FIELDS (FROM TO SUBJECT)] {".(36+24+23+2)."}\r\n",
"From: <test\@localhost.localdomain>\r\n",
"To: <bluewind\@xinu.at>\r\n",
"Subject: Some subject\r\n",
"\r\n",
")\r\n",
"CMD-3 OK NOOP completed (0.001 + 0.000 secs).\r\n"
);
my $socket = Test::MockObject->new();
$socket->mock('readline', sub {my $x = shift @input_lines; ref($x) eq "CODE" ? $x->() : $x;});
$socket->set_true(qw(writeline));
my $config = {
log_id => 'test-id1',
host => 'localhost.localdomain',
port => 993,
username => 'tester1',
password => 'secretPW42',
mailboxes => [qw(INBOX INBOX.test)],
keepalive_timeout => 0.01,
};
my $imap_client = App::ImapNotify::ImapClient->new_no_defaults($config, {sock => $socket});
my $app = App::ImapNotify->new_no_defaults($config, {imap_client => $imap_client, notifier => $notifier});
$app->loop();
is(scalar(@input_lines), 0, "all input lines are read");
eq_or_diff($notifier->_calls(), [
['notify', [$notifier, 'From: <test@localhost.localdomain>', 'Subject: Some subject']]
], "notifier is called correctly");
eq_or_diff([grep { $_->[0] eq "writeline" } $socket->_calls()->@*], [
['writeline', [$socket, "CMD-0 login tester1 secretPW42\r\n"]],
['writeline', [$socket, "CMD-1 select INBOX\r\n"]],
['writeline', [$socket, "CMD-2 notify set (selected (MessageExpunge MessageNew (uid body.peek[header.fields (from to subject)]))) (mailboxes (INBOX INBOX.test) (MessageNew MessageExpunge MailboxName))\r\n"]],
['writeline', [$socket, "CMD-3 noop\r\n"]],
], "notifier is called correctly");
done_testing;
|
