# Former contributor: Tuxbubling <tuxbubling@jabber.fr>, alejandronova
# Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>
pkgname=cdrtools
pkgver=2.01.01a60
pkgrel=1
pkgdesc="Original cdrtools, supporting CD, DVD and BluRay burning"
arch=('i686' 'x86_64')
url="http://cdrecord.berlios.de/private/cdrecord.html"
license=('CDDL')
depends=('acl')
conflicts=('cdrkit')
provides=('cdrkit')
backup=('etc/default/cdrecord' 'etc/default/rscsi')
install=cdrtools.install
source=(ftp://ftp.berlios.de/pub/cdrecord/alpha/cdrtools-$pkgver.tar.gz \
        ftp://ftp.berlios.de/pub/smake/alpha/smake-1.2a41.tar.gz)
md5sums=('62a2c475d3efefb1792f5ca20dfbb557'
         '1442b147193800e27246ac6d000ba890')
         
build() {
  cd "$srcdir"/smake-1.2/psmake
  ./MAKE-all
  cd ..
  ./psmake/smake

  cd "$srcdir"/cdrtools-${pkgver%%a*}
  sed -i 's|/opt/schily|/usr|g' DEFAULTS/Defaults.linux
  sed -i 's|DEFINSGRP=.*|DEFINSGRP=root|' DEFAULTS/Defaults.linux
  
  "$srcdir"/smake-1.2/smake/OBJ/*-linux-*/smake || return 1
  "$srcdir"/smake-1.2/smake/OBJ/*-linux-*/smake INS_BASE="$pkgdir"/usr INS_RBASE="$pkgdir" install
  mv "$pkgdir"/usr/man "$pkgdir"/usr/share/
  rm -rf "$pkgdir"/usr/include
  rm -rf "$pkgdir"/usr/lib
  find "$pkgdir" -type d -perm 775 -exec chmod 755 '{}' ';'
  find "$pkgdir" -type f -perm 4711 -exec chmod 755 '{}' ';'
}

# vim:set ts=2 sw=2 et: