# $Id$
# Maintainer: tobias [ tobias at archlinux org ]

pkgname=gvim
_srcver=7.2
_patchlevel=108
pkgver=${_srcver}.${_patchlevel}
pkgrel=1
pkgdesc="the vim text editor with advanced features enabled, such as a gui mode"
arch=(i686 x86_64)
license=('custom:vim')
url="http://www.vim.org"
depends=("vim>=${pkgver}" 'perl' 'acl' 'libxt' 'gtk2' 'desktop-file-utils' 'python')
makedepends=('pkgconfig')
backup=(etc/gvimrc)
conflicts=('gvim-devel')
provides=('gvim-devel')
install=${pkgname}.install
source=(ftp://ftp.vim.org/pub/vim/unix/vim-${_srcver}.tar.bz2 \
        ftp://ftp.vim.org/pub/vim/extra/vim-${_srcver}-extra.tar.gz \
        ftp://ftp.vim.org/pub/vim/extra/vim-${_srcver}-lang.tar.gz \
        ${pkgname}.desktop fetch_patches.sh)

build()
{
  # patch party
  # pull in patches from vim.org (or the src cache alternatively)
  . ${startdir}/src/fetch_patches.sh
  get_patches || return 1
  cd ${startdir}/src/vim$(echo ${_srcver} | sed "s/\.//")
   # define the place for the global (g)vimrc file (set to /etc/vimrc)
  sed -i 's|^.*\(#define SYS_.*VIMRC_FILE.*"\) .*$|\1|' src/feature.h
  ./configure --prefix=/usr --localstatedir=/var/lib/vim --mandir=/usr/share/man \
    --with-compiledby=ArchLinux --with-features=big \
    --with-x=yes --disable-gpm --with-x=yes --enable-gui=gtk2 \
    --with-global-runtime=/usr/share/vim --with-vim-name=gvim \
    --enable-multibyte --enable-cscope \
    --enable-perlinterp --enable-pythoninterp 
  make || return 1
  # install everything first ...
  make VIMRCLOC=/etc DESTDIR=${startdir}/pkg VIMRTDIR= install

   # ... and clean up what vim already has for us
   # move the binary and fix the (g)* related symlinks
  find ${startdir}/pkg/usr/bin -type l 2> /dev/null | while read symlink; do
    rm ${symlink}
  done
  cd ${startdir}/pkg/usr/bin
  rm -f gvimtutor xxd
  ln -s gvim evim
  ln -s gvim egview
  ln -s gvim gview
  ln -s gvim gvimdiff
  ln -s gvim rgview
  ln -s gvim rgvim

   # delete the manpages/symlinks provided by vi package
  find ${startdir}/pkg/usr/share/man -type d -name 'man1' 2> /dev/null | \
   while read mandir; do
    cd ${mandir}
    rm -f *.1
    ln -s evi.1.gz evim.1.gz
    ln -s vi.1.gz egview.1.gz
    ln -s vi.1.gz gview.1.gz
    ln -s vi.1.gz gvim.1.gz
    ln -s vimdiff.1.gz gvimdiff.1.gz
    ln -s vi.1.gz rgvim.1.gz
    ln -s vi.1.gz rgview.1.gz
  done

  install -Dm644 ${startdir}/pkg/usr/share/vim/gvimrc_example.vim \
    ${startdir}/pkg/etc/gvimrc
   # clean all settings and controls -  served by vi package
  rm -rf ${startdir}/pkg/usr/share/vim
   # freedesktop links
  install -D -m644 ${startdir}/src/${pkgname}.desktop \
    ${startdir}/pkg/usr/share/applications/gvim.desktop
  install -D -m644 ${startdir}/src/vim$(echo ${_srcver} | sed "s/\.//")/runtime/vim48x48.png \
    ${startdir}/pkg/usr/share/pixmaps/gvim.png
}
md5sums=('f0901284b338e448bfd79ccca0041254'
         '35e04482f07c57221c9a751aaa3b8dac'
         'd8884786979e0e520c112faf2e176f05'
         '2be104c0372dd6dae19cb7968c03cd4f'
         'f16f81339ea02b6e1a736264861b7fad')
sha512sums=('e33bfb1b86b769ff4980bc48b9dc70db64c5a44d487206a387cfaefef98fbfee70359e625487c6891f64758bbea5502b2b97104cfa6eb6829a68073ae26a70b6'
            'bcf5d384002a9e9be6d84f5aeb802c3e16e17806d1c87f6687c52b3ce34684f8ad4c1aa5d67810a3205265dd401a1061ad2d0e2fc095de32391c159f6ba04e1a'
            '939571d34b941b1394a49515b359a7606adf8051079492f497d4ead64f58e287ea5ed695473db8ec1f90fdfe57b028f574c6541417025b468d1818ce0bfd9f5a'
            '5f17304022d222822422403bbbea18e47cdf450b73e34a7915d2f60e16cdf62b1673a0d6eaf8a2f1624442f00b40d7a11bf135185d6b9ead03816b0335358d9d'
            '7e94b6235e35c9b894863925d3a52a4723dbc9956989636c337776c0f327aaf183a6e16e91e1841c6618a9fc91a798253fbc5d95c94379a93da323f4cd4f2306')