# Maintainer: xduugu
pkgname=iron
pkgver=4.0.275.2
pkgrel=3
pkgdesc="A web browser based on chromium without Google's tracking 'features'"
arch=('i686' 'x86_64')
url="http://www.srware.net/en/software_srware_iron.php"
license=('custom:BSD')
depends=('alsa-lib' 'libjpeg6' 'libpng12' 'nss' 'ttf-dejavu')
provides=("chromium=$pkgver")
install=$pkgname.install
source=(http://www.srware.net/downloads/$pkgname-linux.tar.gz
        $pkgname{.desktop,.png,.sh} LICENSE)
md5sums=('25d8756de52092b83108ac29e70c635f'
         '22123a1dd05575b0edfdebdae61018fe'
         '60df76c38381e46577505b0c61cea017'
         '6ec430e5597388492b413b152c9587ac'
         '30032c6c531632af6547fa360395acd3')
sha256sums=('8083cd82964890fc128e75a0e0be2de2e4e689a20fad25606eba0e65da35ef36'
            'd45acaf8cc76f13f3274e2915a499e321efb59d5ff4f75425b9089cafeb18fd2'
            '77c29198ff3079f4be5469023a5317c18dd7ef9ce34efd3ae4ca0be09d5de285'
            '746148eba30c710dd2ad091afae102bf609501ebbdf8e2633cc88f2fe5262189'
            'ec68693372a025d4cba5214a0b97c66ae62025c80cc34ef6c01c92b32bd0f2d6')

# x86_64 source
if [[ $CARCH == x86_64 ]]; then
  source[0]=${source[0]/.tar./-64.tar.}
  md5sums[0]='cb8f8f037fc51595965c6fc5e1073429'
  sha256sums[0]='c4dc670eb67030eeba1efad09514570a88f78d03321ee093e3ba96331d63b88f'
fi

build() {
  install -Dm755 $pkgname.sh "$pkgdir/usr/bin/$pkgname" &&
  install -d "$pkgdir/opt" &&
  mv $(echo ${source[0]##*/} | sed 's/\..*//') "$pkgdir/opt/$pkgname" &&
  cd "$pkgdir/opt/$pkgname" &&
  rm -f product_logo_48.png README xdg-settings &&
  ln -s /lib/libBrokenLocale.so.1 libgconf-2.so.4 &&
  chmod a=r,u+w,a+X -R . &&
  chmod a+x $pkgname chrome_sandbox libffmpegsumo.so &&
  cd $OLDPWD || return 1

  install -Dm644 $pkgname.png "$pkgdir/usr/share/pixmaps/$pkgname.png" &&
  install -Dm644 $pkgname.desktop "$pkgdir/usr/share/applications/$pkgname.desktop" &&
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE" || return 1
}

# vim:set ts=2 sw=2 et: