# Maintainer: Otto Allmendinger <otto.allmendinger@googlemail.com>
# Contributor: Malte Rabenseifner <malte@zearan.de> 

pkgname=murmur
pkgver=1.2.2
pkgrel=1
pkgdesc="The voice chat application server for Mumble"
arch=('i686' 'x86_64')
url="http://mumble.sourceforge.net"
license=('GPL')
depends=('avahi' 'lsb-release' 'protobuf' 'qt>=4.4.0')
makedepends=('boost')
conflicts=('murmur-ice' 'murmur-static' 'murmur-git')
backup=("etc/murmur.ini"
    "etc/logrotate.d/murmur"
    "etc/conf.d/murmur" )
install="murmur.install"
source=("http://downloads.sourceforge.net/mumble/mumble-$pkgver.tar.gz"
    "murmur.rc.d"
    "murmur.conf.d"
    "murmur.dbus.conf"
    "murmur.logrotate.d"
)

build() {
    cd ${srcdir}/mumble-$pkgver

    qmake main.pro CONFIG+="no-client no-ice" || return 1
    make || return 1

    sed -e "1i# vi:ft=cfg" \
        -e "s|database=|database=/var/lib/murmur/murmur.sqlite|" \
        -e "s|dbus=session|#dbus=system|" \
        -e "s|#logfile=murmur.log|logfile=/var/log/murmur/murmur.log|" \
        -e "s|#pidfile=|pidfile=/var/run/murmur/murmur.pid|" \
        -e "s|#uname=|uname=murmur|" \
        -i scripts/murmur.ini || return 1

    install -dm755 ${pkgdir}/var/lib/murmur
    install -dm755 ${pkgdir}/var/log/murmur
    install -dm755 ${pkgdir}/var/run/murmur
    install -Dm755 release/murmurd ${pkgdir}/usr/sbin/murmurd
    install -Dm644 scripts/murmur.ini ${pkgdir}/etc/murmur.ini
    install -Dm755 ${startdir}/murmur.rc.d ${pkgdir}/etc/rc.d/murmur
    install -Dm644 ${startdir}/murmur.conf.d ${pkgdir}/etc/conf.d/murmur
    install -Dm644 ${startdir}/murmur.dbus.conf \
                      ${pkgdir}/etc/dbus-1/system.d/murmur.conf
    install -Dm644 ${startdir}/murmur.logrotate.d \
                      ${pkgdir}/etc/logrotate.d/murmur
    install -Dm644 README ${pkgdir}/usr/share/doc/murmur/README
    install -Dm644 man/murmurd.1 ${pkgdir}/usr/share/man/man1/murmurd.1
}

md5sums=('de30ee85170e183b66568b53b04c5727'
         'a577febe880ea104a2b00582b9cb0ddd'
         '11c1cc875e8021739ec2087252cf0533'
         'eddea4cdbd0bde4b960a67e16b5d5478'
         'c56726cb267ead68f37f35c28e36e6fa')