# Contributor: Sebastian.Salich@gmx.de
# Maintainer: Doc Angelo

pkgname=murmur
pkgver=1.1.8
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="The voice chat application server for Mumble"
license=('GPL')
backup=('etc/murmurd.ini')
depends=('qt>=4.4.0' 'libcap')
makedepends=('pkgconfig')
conflicts=('mumble<=1.1.4' 'mumble-server')
options=('!libtool') 
url="http://mumble.sourceforge.net/"
source=("http://downloads.sourceforge.net/mumble/mumble-$pkgver.tar.gz" \
	murmurd \
	murmur.install \
	murmur-config.sh)
md5sums=('a7da012922d39b87c45d9f481d4b5efb'
         'e3c7be4cc45ff64a7b9e36605ac24497'
         '5a9f17491006e979037ac148a3881fe2'
         'ceb7bf98b02ce49837b2ea7640c4b68d')
install=murmur.install

build() {
  cd $srcdir/mumble-$pkgver
 
  # Building murmur
  /usr/bin/qmake main.pro "CONFIG+=no-client no-ice" || exit 1
  make || exit 1

  # create directories and copy files
  install -m755 -D $startdir/murmurd $pkgdir/etc/rc.d/murmurd
  install -m755 -D $startdir/murmur-config.sh $pkgdir/usr/bin/murmur-config.sh
  install -m755 -D ./release/murmurd $pkgdir/usr/sbin/murmurd
  install -m755 -d $pkgdir/usr/share/man/man1
  install -m644 -D ./man/mur* $pkgdir/usr/share/man/man1/
  install -m755 -d $pkgdir/var/lib/murmurd

  # copy and modify murmurd.ini
  sed 's|database=|database=/var/lib/murmurd/murmurd.sqlite|g;s|#logfile=murmur.log|logfile=/var/log/murmurd.log|g' ./scripts/murmur.ini > ./scripts/murmurd.ini
  install -m644 -D ./scripts/murmurd.ini $pkgdir/etc/
  rm ./scripts/murmurd.ini
}