From 9b6ec1f545da1cc4088ddf9cc117747954e58e65 Mon Sep 17 00:00:00 2001
From: David Lawrence <dkl@mozilla.com>
Date: Fri, 26 Feb 2016 17:57:55 +0000
Subject: Bug 1069799 - move the QA repository into the main repository
 r=LpSolit

---
 xt/webservice/user_create.t | 118 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 118 insertions(+)
 create mode 100644 xt/webservice/user_create.t

(limited to 'xt/webservice/user_create.t')

diff --git a/xt/webservice/user_create.t b/xt/webservice/user_create.t
new file mode 100644
index 000000000..38b55e69a
--- /dev/null
+++ b/xt/webservice/user_create.t
@@ -0,0 +1,118 @@
+# This Source Code Form is subject to the terms of the Mozilla Public
+# License, v. 2.0. If a copy of the MPL was not distributed with this
+# file, You can obtain one at http://mozilla.org/MPL/2.0/.
+#
+# This Source Code Form is "Incompatible With Secondary Licenses", as
+# defined by the Mozilla Public License, v. 2.0.
+
+#########################################
+# Test for xmlrpc call to User.Create() #
+#########################################
+
+use 5.10.1;
+use strict;
+use warnings;
+
+use FindBin qw($RealBin);
+use lib "$RealBin/../lib";
+
+use QA::Util;
+use Test::More tests => 75;
+my ($config, $xmlrpc, $jsonrpc, $jsonrpc_get) = get_rpc_clients();
+
+use constant NEW_PASSWORD => 'password';
+use constant NEW_FULLNAME => 'WebService Created User';
+
+use constant PASSWORD_TOO_SHORT => 'a';
+
+# These are the characters that are actually invalid per RFC.
+use constant INVALID_EMAIL => '()[]\;:,<>@webservice.test';
+
+sub new_login {
+    return 'created_' . random_string(@_) . '@webservice.test';
+}
+
+sub post_success {
+    my ($call) = @_;
+    ok($call->result->{id}, "Got a non-zero user id");
+}
+
+$jsonrpc_get->bz_call_fail('User.create',
+    { email => new_login(), full_name => NEW_FULLNAME,
+      password => '*' },
+    'must use HTTP POST', 'User.create fails over GET');
+
+# We have to wrap @tests in the foreach, because we want a different
+# login for each user, separately for each RPC client. (You can't create
+# two users with the same username, and XML-RPC would otherwise try to
+# create the same users that JSON-RPC created.)
+foreach my $rpc ($jsonrpc, $xmlrpc) {
+    my @tests = (
+        # Permissions checks
+        { args  => { email    => new_login(), full_name => NEW_FULLNAME,
+                     password => NEW_PASSWORD },
+          error => "you are not authorized",
+          test  => 'Logged-out user cannot call User.create',
+        },
+        { user  => 'unprivileged',
+          args  => { email    => new_login(), full_name => NEW_FULLNAME,
+                     password => NEW_PASSWORD },
+          error => "you are not authorized",
+          test  => 'Unprivileged user cannot call User.create',
+        },
+
+        # Login name checks.
+        { user  => 'admin',
+          args  => { full_name => NEW_FULLNAME, password => NEW_PASSWORD },
+          error => "argument was not set",
+          test  => 'Leaving out email argument fails',
+        },
+        { user  => 'admin',
+          args  => { email    => '', full_name => NEW_FULLNAME,
+                     password => NEW_PASSWORD },
+          error => "argument was not set",
+          test  => "Passing an empty email argument fails",
+        },
+        { user  => 'admin',
+          args  => { email    => INVALID_EMAIL, full_name => NEW_FULLNAME,
+                     password => NEW_PASSWORD },
+          error =>  "didn't pass our syntax checking",
+          test  => 'Invalid email address fails',
+        },
+        { user  => 'admin',
+          args  => { email    => new_login(128), full_name => NEW_FULLNAME,
+            password => NEW_PASSWORD },
+            error =>  "didn't pass our syntax checking",
+            test  => 'Too long (> 127 chars) email address fails',
+        },
+        { user  => 'admin',
+          args  => { email     => $config->{unprivileged_user_login},
+                     full_name => NEW_FULLNAME, password => NEW_PASSWORD },
+          error =>  "There is already an account",
+          test  => 'Trying to use an existing login name fails',
+        },
+
+        { user  => 'admin',
+          args  => { email    => new_login(), full_name => NEW_FULLNAME,
+                     password => PASSWORD_TOO_SHORT },
+          error => 'password must be at least',
+          test  => 'Password Too Short fails',
+        },
+        { user => 'admin',
+          args => { email    => new_login(), full_name => NEW_FULLNAME,
+                    password => NEW_PASSWORD },
+          test => 'Creating a user with all arguments and correct privileges',
+        },
+        { user => 'admin',
+          args => { email => new_login(), password => NEW_PASSWORD },
+          test => 'Leaving out fullname works',
+        },
+        { user => 'admin',
+          args => { email => new_login(), full_name => NEW_FULLNAME },
+          test => 'Leaving out password works',
+        },
+    );
+
+    $rpc->bz_run_tests(tests => \@tests, method => 'User.create',
+                       post_success => \&post_success);
+}
-- 
cgit v1.2.3-24-g4f1b