Bugzilla/Quantum/Plugin/Hostage.pm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79

package Bugzilla::Quantum::Plugin::Hostage;
use 5.10.1;
use Mojo::Base 'Mojolicious::Plugin';

sub _attachment_root {
  my ($base) = @_;
  return undef unless $base;
  return $base =~ m{^https?://(?:bug)?\%bugid\%\.([a-zA-Z\.-]+)} ? $1 : undef;
}

sub _attachment_host_regex {
  my ($base) = @_;
  return undef unless $base;
  my $val = $base;
  $val =~ s{^https?://}{}s;
  $val =~ s{/$}{}s;
  my $regex = quotemeta $val;
  $regex =~ s/\\\%bugid\\\%/\\d+/g;
  return qr/^$regex$/s;
}

sub register {
  my ($self, $app, $conf) = @_;

  $app->hook(before_routes => \&_before_routes);
}

sub _before_routes {
  my ($c) = @_;
  state $urlbase               = Bugzilla->localconfig->{urlbase};
  state $urlbase_uri           = URI->new($urlbase);
  state $urlbase_host          = $urlbase_uri->host;
  state $urlbase_host_regex    = qr/^bug(\d+)\.\Q$urlbase_host\E$/;
  state $attachment_base       = Bugzilla->localconfig->{attachment_base};
  state $attachment_root       = _attachment_root($attachment_base);
  state $attachment_host_regex = _attachment_host_regex($attachment_base);

  my $stash = $c->stash;
  my $req   = $c->req;
  my $url   = $req->url->to_abs;

  return if $stash->{'mojo.static'};

  my $hostname = $url->host;
  return if $hostname eq $urlbase_host;

  my $path = $url->path;
  return if $path eq '/__lbheartbeat__';

  if ($attachment_base && $hostname eq $attachment_root) {
    $c->redirect_to($urlbase);
    return;
  }
  elsif ($attachment_base && $hostname =~ $attachment_host_regex) {
    if ($path =~ m{^/attachment\.cgi}s) {
      return;
    }
    else {
      my $new_uri = $url->clone;
      $new_uri->scheme($urlbase_uri->scheme);
      $new_uri->host($urlbase_host);
      $c->redirect_to($new_uri);
      return;
    }
  }
  elsif (my ($id) = $hostname =~ $urlbase_host_regex) {
    my $new_uri = $urlbase_uri->clone;
    $new_uri->path('/show_bug.cgi');
    $new_uri->query_form(id => $id);
    $c->redirect_to($new_uri);
    return;
  }
  else {
    $c->redirect_to($urlbase);
    return;
  }
}

1;