summaryrefslogtreecommitdiffstats
path: root/xt/lib/Bugzilla/Test/Search/FieldTestNormal.pm
blob: 1262e19fb1f1517de607a3c9a902ae95a94de886 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
# -*- Mode: perl; indent-tabs-mode: nil -*-
#
# The contents of this file are subject to the Mozilla Public
# License Version 1.1 (the "License"); you may not use this file
# except in compliance with the License. You may obtain a copy of
# the License at http://www.mozilla.org/MPL/
#
# Software distributed under the License is distributed on an "AS
# IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or
# implied. See the License for the specific language governing
# rights and limitations under the License.
#
# The Original Code is the Bugzilla Bug Tracking System.
#
# The Initial Developer of the Original Code is Everything Solved, Inc.
# Portions created by the Initial Developer are Copyright (C) 2010 the
# Initial Developer. All Rights Reserved.
#
# Contributor(s):
#   Max Kanat-Alexander <mkanat@bugzilla.org>

# This is the same as a FieldTest, except that it uses normal URL
# parameters instead of Boolean Charts.
package Bugzilla::Test::Search::FieldTestNormal;
use strict;
use warnings;
use base qw(Bugzilla::Test::Search::FieldTest);

use Scalar::Util qw(blessed);

use constant CH_OPERATOR => {
    changedafter  => 'chfieldfrom',
    changedbefore => 'chfieldto',
    changedto     => 'chfieldvalue',
};

use constant EMAIL_FIELDS => qw(assigned_to qa_contact cc reporter commenter);

# Normally, we just clone a FieldTest because that's the best for performance,
# overall--that way we don't have to translate the value again. However,
# sometimes (like in Bugzilla::Test::Search's direct code) we just want
# to create a FieldTestNormal.
sub new {
    my $class = shift;
    my ($first_arg) = @_;
    if (blessed $first_arg
        and $first_arg->isa('Bugzilla::Test::Search::FieldTest'))
    {
        my $self = { %$first_arg };
        return bless $self, $class;
    }
    return $class->SUPER::new(@_);
}

sub name {
    my $self = shift;
    my $name = $self->SUPER::name(@_);
    return "$name (Normal Params)";
}

sub search_params {
    my ($self) = @_;
    my $field = $self->field;
    my $operator = $self->operator;
    my $value = $self->translated_value;
    if ($operator eq 'anyexact') {
        $value = [split(',', $value)];
    }
    
    if (my $ch_param = CH_OPERATOR->{$operator}) {
        if ($field eq 'creation_ts') {
            $field = '[Bug creation]';
        }
        return { chfield => $field, $ch_param => $value };
    }
    
    if ($field eq 'delta_ts' and $operator eq 'greaterthaneq') {
        return { chfieldfrom => $value };
    }
    if ($field eq 'delta_ts' and $operator eq 'lessthaneq') {
        return { chfieldto => $value };
    }
    
    if ($field eq 'deadline' and $operator eq 'greaterthaneq') {
        return { deadlinefrom => $value };
    }
    if ($field eq 'deadline' and $operator eq 'lessthaneq') {
        return { deadlineto => $value };
    }
    
    if (grep { $_ eq $field } EMAIL_FIELDS) {
        $field = 'longdesc' if $field eq 'commenter';
        return {
            email1           => $value,
            "email${field}1" => 1,
            emailtype1       => $operator,
            # Used to do extra tests on special sorts of email* combinations.
            %{ $self->test->{extra_params} || {} },
        };
    }

    $field =~ s/\./_/g;
    return { $field => $value, "${field}_type" => $operator };
}

1;