#!/usr/bin/perl
use warnings;
use strict;
use File::Basename;
use Cwd qw(cwd abs_path);
use File::MimeInfo qw(mimetype);
use Image::Magick;
use Getopt::Long;
use Module::Load;
use Pod::Usage;

my $templatedir = abs_path(dirname($0))."/generate_gallery.d";

my $startdir = cwd();

my %opts = ();

$opts{template} = "$templatedir/template.html";
$opts{thumbnailsize} = 200;

GetOptions(\%opts, "exif|e", "verbose|v", "help|h", "filenamedesc", "template=s", "thumbnailsize|s=i", "htmlonly") or pod2usage(2);
pod2usage(0) if $opts{help};

pod2usage(-verbose => 0) if (@ARGV== 0);

if ($opts{exif}) {
	load Image::ExifTool, "ImageInfo";
};

$opts{template} = abs_path($opts{template});
unless (-r $opts{template}) {
	print STDERR "Error: template file not readable: $!\n";
	exit 1;
}

for my $dir (@ARGV) {
	chdir $startdir;
	unless (-d $dir) {
		print "Argument is not a directory: $dir. Ignoring.\n" if $opts{verbose};
		next;
	}
	my $abs_dir = abs_path $dir;
	chdir $abs_dir;
	mkdir "thumbs" unless -d "thumbs";
	my $html;

	for my $file (glob("*")) {
		my $description = "";
		unless (mimetype($file) =~ /^image\/.*/) {
			print "ignoring non-image: $dir/$file\n" if $opts{verbose};
			next;
		}
		
		unless ( -e "$abs_dir/thumbs/$file") {
			print "processing $dir/$file ...\n";
			my $img = new Image::Magick;
			$img->Read("$abs_dir/$file");
			$img->Thumbnail(geometry=>$opts{thumbnailsize}."x".$opts{thumbnailsize});
			$img->Write("$abs_dir/thumbs/$file");
		}

		if ($opts{filenamedesc}) {
			my $basename = basename($file);
			$basename =~ s/(.*)\..*/$1/;
			$description = $basename;
			$description .= ": " if ($opts{exif});
		}
		if ($opts{exif}) {
			my $tags = ImageInfo($file, "Aperture", "ShutterSpeed", "FocalLength");
			$description .= $tags->{ShutterSpeed}."s, ".$tags->{FocalLength}." @ F ".$tags->{Aperture};
		}

		$html .= "<div class=\"thumbnail\">\n";
		$html .= "<a rel=\"images\" class=\"thumbnail\" ";
		$html .= "title=\"$description\"" if $description;
		$html .= "href=\"$file\">\n";
		$html .= "<img class=\"thumbnail\" alt=\"\" src=\"thumbs/$file\" />\n";
		$html .= "</a>\n</div>\n";
	}
	open TEMPLATE, "<", "$opts{template}";
	open OUTPUT, ">", "$abs_dir/index.html";
	while (<TEMPLATE>) {
		if (/%%CONTENT%%/) {
			print OUTPUT $html;
		} else {
			print OUTPUT $_;
		}
	}
	close TEMPLATE;
	close OUTPUT;
	unless ($opts{htmlonly}) {
		system "cp", "-r", "$templatedir/fancybox", ".";
	}
}
__END__

=head1 NAME

generate_gallery.pl - Generate simple, static HTML gallery

=head1 SYNOPSIS

generate_gallery.pl [options] <directory ...>

 Options:
   --help, -h                  short help message
   --verbose, -v               be verbose during operation
   --exif, -e                  add exif information of each image to the page
   --filenamedesc              add the filename to the description
   --template <file>           change template file to use
   --htmlonly                  don't copy the fancybox directory
   --thumbnailsize, -s <size>  change size of the thumbnails in pixels
                                 (default: 200)

=head1 OPTIONS

=over 8

=item B<--help>, B<-h>

Print a short help message.

=item B<--verbose>, B<-v>

Be verbose.

=item B<--exif>, B<-e>

Add the following exif information to the image description:
shutter speed, ISO, focal length, aperture

This is only recomended for pictures taken with digital cameras.

=item B<--filenamedesc

Add the filename to the image description. The extension will be stripped.

=item B<--template <file>

Change the template file to use. The file should contain the string "%%CONTENT%%".

=item B<--htmlonly

Only generate thumbnails and the html file. This disables copying of fancybox.

=item B<--thumbnailsize, <-s <size>

Change the size of the generated thumbnails in pixels. Default: 200

=back

=head1 DESCRIPTION

This program will generate thumbnails for all images in the given directores and
create a static HTML gallery page.

=cut