rkhunter/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

pkgname=rkhunter
pkgver=1.3.4
pkgrel=2
pkgdesc="An easy-to-use tool which checks machines running UNIX (clones) for the presence of rootkits and other unwanted tools."
arch=('i686' 'x86_64')
url="http://rkhunter.sourceforge.net/"
license=('GPL')
depends=('bash' 'perl' 'wget')
backup=(etc/rkhunter.conf)
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.gz)

md5sums=('31eaacc4d01ad138d1a4283f105088e6')

build() {
  cd $srcdir/${pkgname}-${pkgver}

  install -d -m755 $pkgdir/usr

# fix installer for x86_64
  sed -i -e "s/lib64/lib/g" installer.sh

# install to /usr
  ./installer.sh --layout custom $pkgdir/usr --striproot $pkgdir --install || return 1

# use /etc instead of /usr/etc
  sed -i -e "s#/usr/etc/rkhunter.conf#/etc/rkhunter.conf#g" $pkgdir/usr/bin/rkhunter
  mv $pkgdir/usr/etc $pkgdir/
  mv $pkgdir/usr/var $pkgdir/

# tmp dir path fix
  sed -i -e "s#/usr/var/lib/rkhunter/db#/var/lib/rkhunter/db#g" \
    $pkgdir/etc/rkhunter.conf
  sed -i -e "s#/usr/var/lib/rkhunter/tmp#/var/lib/rkhunter/tmp#g" \
    $pkgdir/etc/rkhunter.conf

# cleanup
  rm -f $pkgdir/var/lib/rkhunter/tmp/{group,passwd}

# we trust in udev
  sed -i 's|^#ALLOWHIDDENDIR=/dev/.udev$|ALLOWHIDDENDIR=/dev/.udev|' $pkgdir/etc/rkhunter.conf
}