1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
|
#!/usr/bin/perl
use warnings;
use strict;
use Email::Stuffer;
use Email::Sender::Transport::SMTP::Persistent;
use File::Basename;
use Encode;
use Encode::Locale;
use File::Slurp;
use threads;
use Thread::Queue;
use Getopt::Long;
use Pod::Usage;
use Encode::MIME::Header;
use Time::HiRes qw(gettimeofday tv_interval);
use Data::Dumper;
use open ':encoding(locale)';
@ARGV = map { decode(locale => $_, 1) } @ARGV;
# ####
# configurable settings
# ####
my $transport = Email::Sender::Transport::SMTP::Persistent->new({
host => 'localhost',
port => 25,
#debug => 1,
});
my $thread_count = 64;
# ####
# end config
# ####
my %opts = ();
Getopt::Long::Configure ("bundling");
pod2usage(-verbose => 0) if (@ARGV== 0);
GetOptions(\%opts, "help|h", "to=s", "from=s", "subject=s", "content-html=s", "content-txt=s", "debug") or pod2usage(2);
pod2usage(0) if $opts{help};
sub trim {
my $string = shift;
$string =~ s/^\s+//;
$string =~ s/\s+$//;
return $string;
}
my $subject = $opts{subject};
my $from = $opts{from};
my @addrlist;
my $content_html;
my $content_txt;
if ($opts{to} =~ m/.+\@.+\..+/) {
push @addrlist, $opts{to};
} else {
if (-r $opts{to}) {
open LIST, "<", $opts{to} or die;
for (<LIST>) {
my $to = trim($_);
next if ($to eq "");
push @addrlist, $to;
}
close LIST;
} else {
print STDERR "Error: can't read recipient file: $!\n";
}
}
if (0+@addrlist < $thread_count) {
$thread_count = 0+@addrlist;
}
die "Error: subject not set\n" unless ($opts{subject});
die "Error: from not set\n" unless ($opts{from});
die "Error: content-txt not set\n" unless ($opts{"content-txt"});
die "Error: can't read content-txt: $!\n" unless (-r $opts{"content-txt"});
die "Error: can't read content-html: $!\n" if ($opts{"content-html"} and not -r $opts{"content-html"});
if ($opts{"content-html"}) {
$content_html = read_file($opts{"content-html"}, binmode => ':utf8');
}
$content_txt = read_file($opts{"content-txt"}, binmode => ':utf8');
print "Building email ... " if $opts{debug};
# create mail
# To will be filled when sending
my $msg = Email::Stuffer->new();
$msg->from($from);
$msg->subject(trim($subject));
$msg->text_body($content_txt);
$msg->html_body($content_html);
$msg->header("Precedence", "bulk");
#$msg->header("List-Unsubscribe", "<mailto:$from>");
$msg->transport($transport);
print "done\n" if $opts{debug};
my $q = Thread::Queue->new();
print "creating worker threads\n" if $opts{debug};
for (my $i = 0; $i < $thread_count; $i++) {
my $thr = threads->new(sub {
while (my $to = $q->dequeue()) {
$msg->to($to);
$msg->send();
print "sent mail in thread".threads->self->tid()."\n" if $opts{debug};
}
$transport->disconnect;
});
}
print "Sending\n";
my $send_time = [gettimeofday];
for (@addrlist) {
$q->enqueue($_);
}
$q->end();
# wait for everyone before exiting
foreach my $thr (threads->list) {
if ($thr->tid && !threads::equal($thr, threads->self)) {
print "waiting for thread ".$thr->tid()." to finish\n" if $opts{debug};
$thr->join;
}
}
print "done after ".tv_interval($send_time)." seconds\n";
__END__
=head1 NAME
mailer.pl - send lots of mails
=head1 SYNOPSIS
mailer.pl options ...
Options:
--help, -h short help message
--to <email or file> recipient(s)
--from <email> from
--subject <string> subject
--content-html <file> body of the mail (html part) (optional)
--content-txt <file> body of the mail (text part)
--debug output extra debug information
=cut
|
