Bug 147833 - start using CGI.pm

r=gerv, justdave

1 files changed, 149 insertions, 0 deletions

diff --git a/Bugzilla/CGI.pm b/Bugzilla/CGI.pm
new file mode 100644
index 000000000..6a9730bc6
--- /dev/null
+++ b/Bugzilla/CGI.pm
@@ -0,0 +1,149 @@
+# -*- Mode: perl; indent-tabs-mode: nil -*-
+#
+# The contents of this file are subject to the Mozilla Public
+# License Version 1.1 (the "License"); you may not use this file
+# except in compliance with the License. You may obtain a copy of
+# the License at http://www.mozilla.org/MPL/
+#
+# Software distributed under the License is distributed on an "AS
+# IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or
+# implied. See the License for the specific language governing
+# rights and limitations under the License.
+#
+# The Original Code is the Bugzilla Bug Tracking System.
+#
+# The Initial Developer of the Original Code is Netscape Communications
+# Corporation. Portions created by Netscape are
+# Copyright (C) 1998 Netscape Communications Corporation. All
+# Rights Reserved.
+#
+# Contributor(s): Bradley Baetz <bbaetz@student.usyd.edu.au>
+
+use strict;
+
+package Bugzilla::CGI;
+
+use CGI qw(-no_xhtml -oldstyle_urls :private_tempfiles);
+
+use base qw(CGI);
+
+use Bugzilla::Util;
+
+# CGI.pm uses AUTOLOAD, but explicitly defines a DESTROY sub.
+# We need to do so, too, otherwise perl dies when the object is destroyed
+# and we don't have a DESTROY method (because CGI.pm's AUTOLOAD will |die|
+# on getting an unknown sub to try to call)
+sub DESTROY {};
+
+sub new {
+    my ($invocant, @args) = @_;
+    my $class = ref($invocant) || $invocant;
+
+    my $self = $class->SUPER::new(@args);
+
+    # Check for errors
+    # All of the Bugzilla code wants to do this, so do it here instead of
+    # in each script
+
+    my $err = $self->cgi_error;
+
+    if ($err) {
+        # XXX - under mod_perl we can use the request object to
+        # enable the apache ErrorDocument stuff, which is localisable
+        # (and localised by default under apache2).
+        # This doesn't appear to be possible under mod_cgi.
+        # Under mod_perl v2, though, this happens automatically, and the
+        # message body is ignored.
+
+        # Note that this error block is only triggered by CGI.pm for malformed
+        # multipart requests, and so should never happen unless there is a
+        # browser bug.
+
+        # Using CGI.pm to do this means that ThrowCodeError prints the
+        # content-type again...
+        #print $self->header(-status => $err);
+        print "Status: $err\n";
+
+        my $vars = {};
+        if ($err =~ m/(\d{3})\s(.*)/) {
+            $vars->{http_error_code} = $1;
+            $vars->{http_error_string} = $2;
+        } else {
+            $vars->{http_error_string} = $err;
+        }
+
+        &::ThrowCodeError("cgi_error", $vars);
+    }
+
+    return $self;
+}
+
+# We want this sorted plus the ability to exclude certain params
+sub canonicalise_query {
+    my ($self, @exclude) = @_;
+
+    # Reconstruct the URL by concatenating the sorted param=value pairs
+    my @parameters;
+    foreach my $key (sort($self->param())) {
+        # Leave this key out if it's in the exclude list
+        next if lsearch(\@exclude, $key) != -1;
+
+        my $esc_key = url_quote($key);
+
+        foreach my $value ($self->param($key)) {
+            if ($value) {
+                my $esc_value = url_quote($value);
+
+                push(@parameters, "$esc_key=$esc_value");
+            }
+        }
+    }
+
+    return join("&", @parameters);
+}
+
+1;
+
+__END__
+
+=head1 NAME
+
+  Bugzilla::CGI - CGI handling for Bugzilla
+
+=head1 SYNOPSIS
+
+  use Bugzilla::CGI;
+
+  my $cgi = new Bugzilla::CGI();
+
+=head1 DESCRIPTION
+
+This package inherits from the standard CGI module, to provide additional
+Bugzilla-specific functionality. In general, see L<the CGI.pm docs|CGI> for
+documention.
+
+=head1 CHANGES FROM L<CGI.PM|CGI>
+
+Bugzilla::CGI has some differences from L<CGI.pm|CGI>.
+
+=over 4
+
+=item C<cgi_error> is automatically checked
+
+After creating the CGI object, C<Bugzilla::CGI> automatically checks
+I<cgi_error>, and throws a CodeError if a problem is detected.
+
+=back
+
+=head1 ADDITIONAL FUNCTIONS
+
+I<Bugzilla::CGI> also includes additional functions.
+
+=over 4
+
+=item C<canonicalise_query(@exclude)>
+
+This returns a sorted string of the paramaters, suitable for use in a url.
+Values in C<@exclude> are not included in the result.
+
+=back